Scratch

var socket:ScratchSocket=new ScratchSocket();

when flag clicked{
  set sc.io.command to 0
  wait 0.05 seconds
  set sc.io.command to "getURL :: http://scratch.mit.edu :: sc.io.returnVoid
}

/*

ScratchSocket

@ This class sends and receives data from Scratch. Data received is sent to sc.Parse to
@ figure out what the heck Scratch wants, whereas other classes use this one to update
@ Scratch sensor variables.

@ Big thanks to Chalkmarrow for explaining how to communicate with Scratch with AS3

@ fullmoon, 2009

*/
package {
    //Import everything we need to work with flash.net.Socket and handle its events
    import flash.events.Event;
    import flash.events.ProgressEvent;
    import flash.events.IOErrorEvent;
    import flash.utils.ByteArray;
    import flash.net.Socket;
    import flash.net.navigateToURL;
    import flash.net.URLRequest;

    public dynamic class ScratchSocket {;
    //Reserve space for socket, but don't declare it
    private var socket:Socket;
    public function ScratchSocket() {
        //Declare socket
        socket=new Socket  ;
        connect();

    }
    private function connect():void {
        //Connect with Scratch on localhost, which responds to port 42001
        socket.connect("localhost",42001);
        socket.addEventListener(Event.CONNECT,socketConnect);
        socket.addEventListener(Event.CLOSE,socketConnect);
        socket.addEventListener(IOErrorEvent.IO_ERROR,socketConnect);
        socket.addEventListener(ProgressEvent.SOCKET_DATA,dataIn);
    }
    public function update(sensor:String,value:String):void {
        //Function to send a sensor update to Scratch
        sendScratchMessage("sensor-update " + sensor + " " + value);
    }
    //Function to send a broadcast to Scratch
    public function broadcast(broadcast:String):void {
        trace("ScratchSocket.broadcast");
        sendScratchMessage('broadcast "' + broadcast + '"');
    }
    private function sendScratchMessage(sendData:String):void {
        //The Scratch Connections protocol requires every message sent to Scratch to
        //be preceded by four bytes indicating the message length
        var bytes:ByteArray=new ByteArray;
        //Here are three '0' bytes
        bytes[0]=0;
        bytes[1]=0;
        bytes[2]=0;
        //Here's the actual message length
        bytes[3]=sendData.length;
        //Now we write the preceder plus the actual message to the socket
        for (var i:Number=0; i < 4; i++) {
            socket.writeByte(bytes[i]);
        }
        //Here comes the airplane!
        socket.writeMultiByte(sendData,"us-ascii");
        socket.flush();
    }
    private function socketConnect(Event):void {
        //Handle connection events linked in constructor
        switch (Event.type) {
            case 'connect' :
                trace("connection successful");
                broadcast("jump");
                break;
            case 'close' :
                trace("connection failed");
                connect();

                break;
            case 'ioError' :
                trace("connection failed through IOError");
                break;
        }
    }
    private function dataIn(event:ProgressEvent):void {
        trace("ScratchSocket.dataIn");
        //Create an empty string
        var inString:String = "";
        while (socket.bytesAvailable) {
            //Read the next part of the socket data into inString
            inString+=socket.readUTF();
        }
        //Send inString off to class SCparse for evaluation
        evaluate(inString);
    }
    // Parse the data received from Scratch
    private function evaluate(input:String) {
        trace("ScratchSocket.evaluate("+input+")");
        // Look for broadcast from Scratch
        // Matches any string starting with 'broadcast ' followed by a string of non-return characters in "quotes"
        var pattern1:RegExp = /broadcast\s\"(.*)"/;
        var result:Object = pattern1.exec(input);
        if (result != null) {
            trace('Scratch broadcasted:'+result[1]);
        }
        // Look for sensor-update from Scratch
        // Matches any sensor-update string Scratch sends
        var pattern2:RegExp = /sensor-update\s\"Scratch-(.*)\"\s\"(.*)\"/;
        result = pattern2.exec(input);
        if (result != null) {
            trace('Scratch changed variable '+result[1]+' to '+result[2]);
            //If the variable changed is 'sc.io.command' then interpret it.
            if (result[1]=="sc.io.command") {
                interpret(result[2]);
            }
        }
    }
    private function interpret(input:String):void {
        trace("ScatchSocket.interpret("+input+")");
        var command:Array=input.split(" :: ");
        trace(command);
        var returnVal="";
        //If the command returns to an invalid sensor then return to the default sensor, 'sc.io.defaultReturn'.
        if (command[2].slice(0,6)!="sc.io.") {
            command[2]="sc.io.defaultReturn";
        }
        //Find out what the command wants
        switch (command[0]) {
            case "getURL" :
                trace("sc.getURL");
                navigateToURL(new URLRequest(command[1]));
                returnVal="success";
                update(command[2],returnVal);
                break;
            case "nospace" :
                trace("sc.concat");
                var a:Array=command[1].split(" ");
                for (var i=0; i<a.length; i++) {
                    if (a[i]=="") {
                        a[i]=" ";
                    }
                }


                var s:String=a.join("");
                returnVal=s;
                update(command[2],returnVal);

        }


    }

}
}

set sc.io.command to "nospace :: t h i s  i s  c o o l :: sc.io.sayThis"
say(sensor value(sc.io.sayThis))